Run IE7 Beta 2 Standalone in 5 easy steps

The IE7 Standalone mode is not offically supported so try this at your own risk. Use this only if you are a web designer and wish to see how your pages will render in IE7. If you want the full features of IE7 the best option is to install it without using this hack.

1) Download IE7 Beta2
2) Rename the file IE7B2P-WindowsXP-x86-enu.exe to IE7B2P-WindowsXP-x86-enu.cab
3) Open the file using WinZip or WinRar and extract the contents to any directory eg: c:\IE7
4) Create a new file IE7.vbs and copy the code given below into it. Save it into the directory where you extracted the files and save it as IE7.vbs

Option Explicit 

Dim objFSO, objReg, objShell, tf, obj

const HKEY_CLASSES_ROOT = &H80000000
const HKEY_CURRENT_USER = &H80000001
const HKEY_LOCAL_MACHINE = &H80000002
const HKEY_USERS = &H80000003 

Sub DeleteRegistryKey(LNGHKEY, strSubkey)
    Dim reg, aSubkeys, s
    Set reg = _
GetObject("WinMgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
    reg.EnumKey LNGHKEY, strSubkey, aSubkeys
    If Not IsNull(aSubkeys) Then
        For Each s In aSubkeys
            Call DeleteRegistryKey(LNGHKEY, strSubKey & "\" & s)
        Next
    End If
    On Error Resume Next
        reg.DeleteKey LNGHKEY, strSubKey
    On Error GoTo 0
End Sub

Set objReg   = _
GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
Set objShell = CreateObject("WScript.Shell")
Set objFSO   = CreateObject("Scripting.FileSystemObject") 

Call DeleteRegistryKey(HKEY_CLASSES_ROOT, _
"CLSID\{C90250F3-4D7D-4991-9B69-A5C5BC1C2AE6}")
Call DeleteRegistryKey(HKEY_CLASSES_ROOT, _
"Interface\{000214E5-0000-0000-C000-000000000046}")

objReg.SetStringValue HKEY_LOCAL_MACHINE, _
 "SOFTWARE\Microsoft\Internet Explorer\Version Vector","IE","7.0000"

objFSO.MoveFile "SHLWAPI.DLL", "SHLWAPI.DLL.BAK"

Set tf = objFSO.CreateTextFile("IEXPLORE.exe.local", True)
tf.Write (" ")
tf.Close 

objShell.Run ".\iexplore.exe about:blank"  ',, true
WScript.Sleep 7000

objFSO.MoveFile "SHLWAPI.DLL.BAK", "SHLWAPI.DLL"

objReg.SetStringValue HKEY_LOCAL_MACHINE, _
"SOFTWARE\Microsoft\Internet Explorer\Version Vector","IE",""
Call DeleteRegistryKey(HKEY_CLASSES_ROOT, _
"CLSID\{C90250F3-4D7D-4991-9B69-A5C5BC1C2AE6}")
Call DeleteRegistryKey(HKEY_CLASSES_ROOT, _
"Interface\{000214E5-0000-0000-C000-000000000046}")

5) Now double click IE7.vbs to use IE7. You can also create a shortcut for IE7.vbs

If you want to use a batch file instead of a VBScript file you can try this out. I take no credit for this script. I just converted the batch file into a VB Script, for more information check this out . The main reason for using a VB Script file was that when you use the batch file a console window remains open till IE7 is being executed. The other reason is that when IE7 is being extecuted IE6 will not work. If you use the VB Script you can use IE6 and IE7 at the same time.

Technorati Tags: ie7, vbscript